-- NOTE
-- This script uses the SatImage OSAX
-- Available from www.satimage.fr/software/
-- all calls to the osax are marked with comments

set qtex to (path to "wcmp") -- 'special' code for OSX Quicktime extensions folder

tell application "Finder"
	set qtItems to (items of qtex whose kind is "Package")
end tell

set thingsOut to ""
repeat with thisQTExt in qtItems
	
	set thisQTExt to thisQTExt as alias
	set componentPackageName to (name of (info for thisQTExt))
	set AppleScript's text item delimiters to "."
	set componentName to (text items 1 thru -2 of componentPackageName) as string
	set AppleScript's text item delimiters to ""
	
	set thisQTExtStr to thisQTExt as string
	set thisQTresource to alias (thisQTExtStr & ":Contents:Resources:" & componentName & ".rsrc")
	
	set thng to "thng"
	
	set resourceIDs to (list resources thng from thisQTresource) -- SatImage
	set thingCount to (count resourceIDs)
	
	repeat with thisThingIndex from 1 to thingCount
		set resID to (item thisThingIndex of resourceIDs)
		set theresource to (load resource resID type thng from thisQTresource as string) -- SatImage		
		
		tell theresource
			set thingType to ((characters 1 thru 4) as string)
			set subType to ((characters 5 thru 8) as string)
			set manufacturer to ((characters 9 thru 12) as string)
			set infoType to ((characters 27 thru 30) as string)
			set infoMSB to character 31 -- high byte
			set infoLSB to character 32 -- low byte
		end tell
		
		set unsignedInfoMSB to (ASCII number infoMSB) * 256
		set unsignedInfoLSB to (ASCII number infoLSB)
		
		set unsigned to (unsignedInfoMSB + unsignedInfoLSB)
		set srtrnID to (unsigned - 65536)
		
		try
			set infoString to (load resource srtrnID type infoType from thisQTresource as string) -- SatImage
			
		on error msg number n
			if n is -192 then -- a resource wasn't found
				log (thingType & " " & subType)
				log (infoType & " " & srtrnID)
				set infoString to " No name!"
			else
				error number n -- just do the error thing as normal
			end if
		end try
		
		repeat while character 1 of infoString is "" -- strip first character if it is (ascii character 12)
			set infoString to ((characters 2 thru end of infoString) as string)
		end repeat
		
		set thingsOut to thingsOut & thingType & "	"
		set thingsOut to thingsOut & subType & "	"
		set thingsOut to thingsOut & manufacturer & "	"
		set thingsOut to thingsOut & infoString & "	"
		set thingsOut to thingsOut & return
		
	end repeat
end repeat

set the clipboard to thingsOut

beep
display dialog "All done. Things copied to clipboard." buttons "OK" default button 1 giving up after 1

return thingsOut -- in case people want to see it in script editor or something

--